Guide Aero Glass Media Player in XP ...<Tutorial>

Status
Not open for further replies.
Coming up.

48985127ba0.jpg


WMP on Vista

20080328001428du5.jpg


foobar2000 on XP

Take your pick. :ohyeah:

http://www.techenclave.com/applications/aero-glass-media-player-xp-showoff-107533.html

References:

Foobar2000:Titleformat Reference

Foobar2000:Titleformat Introduction - Hydrogenaudio Knowledgebase

PanelsUI Introduction:

http://wiki.hydrogenaudio.org/index.php?title=Foobar2000:Components_0.9/Panels_UI_(foo_ui_panels)

PanelsUI Basic User's Guide

Foobar2000:Components 0.9/Panels UI (foo ui panels)/User's Guide - Hydrogenaudio Knowledgebase

PanelsUI Basic User's Guide

Foobar2000:Components 0.9/Panels UI (foo ui panels)/Intermediate User's Guide - Hydrogenaudio Knowledgebase

PanelsUI Commands Reference

Old - Foobar2000:Components 0.9/Panels UI (foo ui panels)/Commands 0.13.x - Hydrogenaudio Knowledgebase

New - Foobar2000:Components 0.9/Panels UI (foo ui panels)/Commands - Hydrogenaudio Knowledgebase

PanelsUI Library Filter

Foobar2000:Components 0.9/Panels UI (foo ui panels)/Library Filter - Hydrogenaudio Knowledgebase

PanelsUI Single Column Playlist

Foobar2000:Components 0.9/Panels UI (foo ui panels)/Single Column Playlist - Hydrogenaudio Knowledgebase

Ok. Almost all the code is uploaded.

More pages for plugins needed, their settings, my images for the config, how to get started etc. coming up.

The tutorial will be concluded soon.

[BREAK=Requirements]

Components needed

[BREAK=Getting started]

Make sure you have all the plugins required in the components directory before you start (.\foobar2000\components directory).

Create a new layout file in PanelUI interface under the Display menu in foobar and name it anything.

20080327221538lw9.png


Browse to the folder where the layout file is located (generally the .\foobar2000\PanelsUI\ directory).

You maykeep the layout file anywhere else, like in a subfolder or even a different drive but remember to select that layout from the PanelsUI options.

Download the Image resources (to be uploaded) and keep them in a folder named images in the same place where the layout file is located.

[BREAK=Main Page]

After starting foobar, you'll see something like this.

At this point, make sure that this refers to the layout file you just created. the default.pui file also looks like this. (if you want this to be the default layout, just copy the images folder in your PanelsUI directory and don't bother)

20080327221807rm2.png


Right click at the bottom bar as shown and enter the following code:

Code: 
// Global

$if(%isplaying%,$settitle([%title%[ / %artist%][ / %album%]]),$settitle(Media Player))

//// Persistent Variables

$setpvar(Font.Main.active,$font(Segoe UI Bold,12,glow-255-255-255 glowblur-10 glowalpha-128,255-255-255))

$setpvar(Font.Main.inactive,$font(Segoe UI,12,glow-255-255-255 glowblur-10 glowalpha-64,255-255-255))

// Background

$drawrect(0,0,%_width%,%_height%,brushcolor-255-255-255 pencolor-null)

//// Image Overlays

$imageabs2(%_width%,%_height%,,,,,,,C:\Documents & Settings\User Name\Local Settings\Application Data\Microsoft\Wallpaper1.bmp, NOKEEPASPECT ALPHA-250)

$imageabs2($eval(%_width%-19),46,,,,,10,8,/images\Gloss.PNG, NOKEEPASPECT alpha-192)

$imageabs2($eval(%_width%-16),$eval(%_height%-160),,,,,8,80,/images\Glass.PNG,NOKEEPASPECT VALIGN-T)

//// Rectangle Overlays

$drawrect(10,8,$eval(%_width%-19),46,brushcolor-null pencolor-255-255-255 blur-1 alpha-192)

$drawrect(8,56,$eval(%_width%-17),22,brushcolor-255-255-255 pencolor-255-255-255 alpha-128 blur-4)

$drawrect(8,80,$eval(%_width%-16),$eval(%_height%-160),brushcolor-255-255-255 pencolor-255-255-255 ALPHA-32 BLUR-8 )

// PerTrack

//// Panels

$panel(Search,Quick Search Toolbar,$eval(3*$eval(%_width%-16)/4+8),57,$eval($eval(%_width%-16)/4-32),20,)

$panel(Controls,Track Display,8,$eval(%_height%-72),$eval(%_width%-16),72,)

$panel(Seekbar,Seekbar,16,$eval(%_height%-72),$eval(%_width%-32),16,)

$select($add($getpvar(main.mode),1),

$panel(Now Playing,Track Display,8,80,$eval(%_width%-16),$eval(%_height%-160),),

$panel(Library,Track Display,8,80,$eval(%_width%-16),$eval(%_height%-160),),

$panel(View,Track Display,8,80,$eval(%_width%-16),$eval(%_height%-160),),

$panel(Details,Track Display,8,80,$eval(%_width%-16),$eval(%_height%-160),))

//// Buttons

$button2(200,18,0,0,100,32,'$ifequal($getpvar(main.mode),0,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Now Playing','$getpvar(Font.Main.active)Now Playing',PVAR:SET:main.mode:0,TOOLTIP:"Toggle Now Playing"),

$button2(400,18,0,0,100,32,'$ifequal($getpvar(main.mode),1,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Library','$getpvar(Font.Main.active)Library',PVAR:SET:main.mode:1,TOOLTIP:"Toggle Library"),

$button2(600,18,0,0,100,32,'$ifequal($getpvar(main.mode),2,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))View','$getpvar(Font.Main.active)View',PVAR:SET:main.mode:2,TOOLTIP:"Toggle View"),

$button2(800,18,0,0,100,32,'$ifequal($getpvar(main.mode),3,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Details','$getpvar(Font.Main.active)Details',PVAR:SET:main.mode:3,TOOLTIP:"Toggle Details")

$button(18,12,0,,36,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_left.PNG,PVAR:SET:main.mode:$ifgreater($getpvar(main.mode),0,$eval($getpvar(main.mode)-1),0),TOOLTIP:"Previous")

$button(18,12,36,,36,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_right.PNG,PVAR:SET:main.mode:$ifgreater(3,$getpvar(main.mode),$eval($getpvar(main.mode)+1),3),TOOLTIP:"Next")

$button(18,12,72,,18,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_up.PNG,Preferences,)

$button(10,57,0,0,0,0,/images\Buttons\Browse.PNG,/images\Buttons\Browse_h.PNG,Open Containing Folder,)

$button($eval(%_width%-38),57,0,0,0,0,/images\Buttons\Arrow_l.PNG,/images\Buttons\Arrow_r.PNG,1 - Queue Manager,)

$imageabs2(,,,,,,$eval(3*$eval(%_width%-16)/4-117),57,/images\$if(%rating%,$ifgreater(%rating%,5,5,%rating%),0)s1.png,)

$button($eval(3*$eval(%_width%-16)/4-115),59,0,0,0,0,/images\Rating\star.PNG,/images\Rating\$ifgreater(%rating%,0,star_h.PNG,star_d.PNG),$ifequal(%rating%,1,TAG:SET:rating:,TAG:SET:rating:1),)

$button($eval(3*$eval(%_width%-16)/4-102),59,0,0,0,0,/images\Rating\star.PNG,/images\Rating\$ifgreater(%rating%,1,star_h.PNG,star_d.PNG),TAG:SET:rating:2,)

$button($eval(3*$eval(%_width%-16)/4-89),59,0,0,0,0,/images\Rating\star.PNG,/images\Rating\$ifgreater(%rating%,2,star_h.PNG,star_d.PNG),TAG:SET:rating:3,)

$button($eval(3*$eval(%_width%-16)/4-76),59,0,0,0,0,/images\Rating\star.PNG,/images\Rating\$ifgreater(%rating%,3,star_h.PNG,star_d.PNG),TAG:SET:rating:4,)

$button($eval(3*$eval(%_width%-16)/4-63),59,0,0,0,0,/images\Rating\star.PNG,/images\Rating\$ifgreater(%rating%,4,star_h.PNG,star_d.PNG),TAG:SET:rating:5,)

//// Breadcrumb Address

$puts(d1,$if(%isplaying%,$directory(%path%,1),Album))

$puts(d2,$if(%isplaying%,$directory(%path%,2),Artist))

$puts(d3,$if(%isplaying%,$directory(%path%,3),Library))

$puts(string,[$get(d3)     }   ][$get(d2)     }   ]$get(d1))

$puts(charWidth,$div($calcwidth($get(string)),$len($get(string))))

$puts(areaWidth,$sub(%_width%,165))

$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)

$alignabs(60,58,$get(areaWidth),20,,)

$replace(

    $ifgreater($calcwidth($get(string)),$get(areaWidth),

        $left($get(string),$sub($sub($len($get(string)),$div($sub($calcwidth($get(string)),$get(areaWidth)),$get(charWidth))),3))'...'

    ,

        $get(string)

    )

    ,},$font(wingdings 3,7,,0-0-0)}$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)

)
20080327222206cv0.png


Replace C:\Documents & Settings\User Name\Local Settings\Application Data\Microsoft\Wallpaper1.bmp

with accordingly (The Wallpaper bitmap used by windows in your %USERPROFILE%)

If you are doing things correctly, you'll see something like this:

20080327222237ex3.png


[BREAK=Controls (Track Display)]

Now will be a good time to maximize the window if you didn't do that till now.:ohyeah:

20080327223217oo2.png


The bottom panel where it says "No track" is the Controller panel and the top one where it says "No Track" is the Now Playing track display (obviously :P).

Right Click the bottom panel. You'll see some code already.

20080327223256sp8.png


Select it all (Ctrl+A) and delete it. Now enter the following code:

Code: 
// Background

$imageabs2(%_width%,$eval(2*%_height%-66),,,,,,,/images\Buttons\ControlBar.PNG,alpha-220)

// PerTrack

//// Buttons

$if($stricmp(%cwb_playback_order%,'Shuffle (tracks)'),$button($eval(%_width%/2-185),28,,,,,/images\Buttons\Shuffle_h.PNG,/images\Buttons\Shuffle_h.PNG,'Default',),$button($eval(%_width%/2-185),28,,,,,/images\Buttons\Shuffle.PNG,/images\Buttons\Shuffle_h.PNG,'Shuffle (tracks)',TOOLTIP:"Shuffle"))

$if($stricmp(%cwb_playback_order%,'Repeat (track)'),$button($eval(%_width%/2-155),28,,,,,/images\Buttons\Repeat_h.PNG,/images\Buttons\Repeat_h.PNG,'Default',),$button($eval(%_width%/2-155),28,,,,,/images\Buttons\Repeat.PNG,/images\Buttons\Repeat_h.PNG,'Repeat (track)',TOOLTIP:"Repeat"))

$button($eval(%_width%/2-108),16,,,30,30,$if(%ispaused%,/images\Buttons\Play.PNG,$if(%isplaying%,/images\Buttons\Pause.PNG,/images\Buttons\Play.PNG)),$if(%ispaused%,/images\Buttons\Stop_h_0.PNG,$if(%isplaying%,/images\Buttons\Stop_h.PNG,/images\Buttons\Stop_h_0.PNG)),Stop,)

$button($eval(%_width%/2-108),16,30,,60,30,$if(%ispaused%,/images\Buttons\Play.PNG,$if(%isplaying%,/images\Buttons\Pause.PNG,/images\Buttons\Play.PNG)),$if(%ispaused%,/images\Buttons\Previous_h_0.PNG,$if(%isplaying%,/images\Buttons\Previous_h.PNG,/images\Buttons\Previous_h_0.PNG)),Previous,)

$button($eval(%_width%/2-108),16,90,,30,30,$if(%ispaused%,/images\Buttons\Play.PNG,$if(%isplaying%,/images\Buttons\Pause.PNG,/images\Buttons\Play.PNG)),$if(%ispaused%,/images\Buttons\Play_h.PNG,$if(%isplaying%,/images\Buttons\Pause_h.PNG,/images\Buttons\Play_h.PNG)),Play or Pause,)

$button($eval(%_width%/2-108),16,120,,60,30,$if(%ispaused%,/images\Buttons\Play.PNG,$if(%isplaying%,/images\Buttons\Pause.PNG,/images\Buttons\Play.PNG)),$if(%ispaused%,/images\Buttons\Next_h_0.PNG,$if(%isplaying%,/images\Buttons\Next_h.PNG,/images\Buttons\Next_h_0.PNG)),Next,)

$button($eval(%_width%/2+88),28,,,,,/images\Buttons\Volume.PNG,/images\Buttons\Volume_h.PNG,'Volume mute',)

$panel(Volume,Volume,$eval(%_width%/2+116),30,72,16,)

$panel(Spectrum Minor,Channel spectrum panel,$eval(3*%_width%/4-36),24,$eval(%_width%/4+36),$eval(%_height%-32),)

// PerSecond

//// info cycle

//////////////////////

$ifgreater(%_width%,920,

    $font(segoe ui,10,glow-255-255-255 glowblur-5 glowalpha-128,255-255-255)

    $alignabs(57,14,$sub($div(%_width%,2),355),50,left,middle)

    $if(%isplaying%,

        $select($add(1,$div($mod(%_time_elapsed_seconds%,12),3)),

            $if(%artist%,$caps2(%artist%),Artist unknown)

        ,

            $if(%album%,$caps2(%album%)[' ('%date%')'],Album unknown)

        ,

            $if(%title%,[%tracknumber%'. ']%title%,Title unknown)

        ,

            %codec% @ %bitrate%kbps

        )

    ,

        Stopped

    )

,

)

//// Time elapsed

//////////////////////

$font(segoe ui,11, glow-255-255-255 glowblur-5 glowalpha-128,255-255-255)

$alignabs($ifgreater(%_width%,683,$sub($div(%_width%,2),295),13),29,300,20,,)

$if(%isplaying%,

    $ifgreater($mul(%_time_elapsed%,1),9

        ,

        ,

        

    )

    %_time_elapsed% / %length%

    ,

    00:00

)

$alignabs(229,29,300,20,,)

$ifgreater(%_width%,683,

    $if(%isplaying%,

        $if(%ispaused%,

            $imageabs2(,,,,,,8,32,/images\Buttons\Pause_i.PNG,)

        ,

            $imageabs2(,,,,,,8,32,/images\Buttons\Play_i.PNG,)

        )

    ,

        $imageabs2(,,,,,,8,32,/images\Buttons\Stop_i.PNG,)

    )

,

)
Shutdown foobar2000 and restart (properly) to save the code till here.

If you did everything correctly, you'll see this:

20080327223320jc8.png


Configure the Channel Spectrum Panel as shown in the figure or as you find it appealing:

20080327223401xi0.png


Proceed to see how this looks like.

[BREAK=Now Playing (Track Display)]

Now for the Now Playing Panel

20080327225109xd2.png


Enter the code in the ghastly looking Center Panel. Make sure the Now Playing mode is highlighted on the top bar or you'll mess everything up.

20080327225810tm1.png


Code: 
// PerTrack

$panel(Left Playing,Track Display,,,$eval(%_width%/4),%_height%,)

$panel(CenterPlaying,Track Display,$eval(%_width%/4),,$eval(%_width%/2),%_height%,)

$panel(RightPlaying,Track Display,$eval(3*%_width%/4),,$eval(%_width%/4),%_height%,)
The code will divide the panel into three as shown.

20080327231806ev4.png


[BREAK=Now Playing > LeftPlaying , CenterPlaying, RightPlaying (Track Displays)]

I guess the following is self explanatory:

20080327231916cq9.png


Code for LeftPlaying (Track Display):

Code: 
//PerTrack

$if(%isplaying%,$imageabs2(,,,,,,16,48,/images\Rating\$if(%rating%,$ifgreater(%rating%,5,5,%rating%),0)_star.PNG,),)

$padding(16,24)

$align(left,top)

$font(SegoeUI,12, bold shadow-128-128-128,255-255-255)

[%genre%$char(10)]

$padding(,84)

$font(SegoeUI,10, shadow-128-128-128,255-255-255)

$align(left,top)

[Audio on: %publisher%$char(10)$char(10)]

[Composer: %composer%$char(10)$char(10)]

[Lyricist: %writer%$char(10)]

// PerSecond

$padding(16,24)

$font(SegoeUI,15, bold shadow-128-128-128,255-255-255)

$align(left,bottom)

[%_time_elapsed% / %_length%]

$padding(,84)

$font(SegoeUI,10, bold shadow-128-128-128,255-255-255)

$align(left,bottom)

[%codec%[ $info(encoding)] 

$if(%isplaying%,$get(info)$div(1411,%__bitrate%).$substr($muldiv(1411,100,%__bitrate%),2,3):1 '('$get(info)$muldiv(%__bitrate%,100,1411)$get(anno)'%)',)

$char(10)]

[$info(tool)$char(10)]

[%bitrate% kbps] [%codec_profile%]$char(10)

[%samplerate% Hz][ %bitspersample%  bits]$char(10)

[$if2($info(mp3_stereo_mode),%channels%)$char(10)]

[$char(10)%ENCODEDBY%$char(10)]

[$char(10)$if(%__replaygain_track_gain%, Track Gain: %__replaygain_track_gain%)]

[$char(10)$if(%__replaygain_album_gain%, Album Gain: %__replaygain_album_gain%)]
Code for CenterPlaying (Track Display):

Code: 
// PerTrack

$if(%isplaying%,$imageabs2(330,330,,,,,$eval(%_width%/2-155),$eval(%_height%/2-155),/images\Drop Shadow.png,NOKEEPASPECT))

$if(%isplaying%,$imageabs2(340,310,,,,,$eval(%_width%/2-187),$eval(%_height%/2-155),/images\NO.ART.png,NOKEEPASPECT))

$imageabs2(300,300,,,,,$eval(%_width%/2-150),$eval(%_height%/2-150),$replace(%path%,%filename_ext%,)*.jpg,NOKEEPASPECT)

$imageabs2(300,300,,,,,$eval(%_width%/2-150),$eval(%_height%/2-150),$replace(%path%,%filename_ext%,)$if2(%cover front%,$if2(%album%,$if2(%artist%,folder)).*),NOKEEPASPECT)

$padding(0,16)

$align(center,top)

$font(SegoeUI,20, bold italic shadow-128-128-128,255-255-255)

[%title%$char(10)]

$align(center,bottom)

$font(SegoeUI,15, bold shadow-128-128-128,255-255-255)

[%artist%$char(10)]

[$if2(%album%,)[$if([%date%], $char(40)%date%$char(41),)]]
Code for RightPlaying (Lyric Show):

Code: 
$if(%isplaying%,

$panel(Lyric Show,Lyric Show,0,8,$eval(%_width%-8),$eval(%_height%-16),))

)
If all is good, it will look like this:

20080327232029bz3.jpg


End of Now Playing Mode

Click on the Library button on the top bar.

[BREAK=Library (Track Display)]

Enter the code as shown

20080327232312ch2.png


Code: 
// Global

$ifequal($getpvar(sidebar.mode),0,$setpvar(sidebar.caption,Sort),)

$ifequal($getpvar(sidebar.mode),1,$setpvar(sidebar.caption,Info),)

$ifequal($getpvar(sidebar.mode),2,$setpvar(sidebar.caption,Filter),)

// Background

$imageabs2($eval(%_width%/4-16),38,,,,,8,8,/images\Gloss.PNG, NOKEEPASPECT alpha-128)

//// Rectangle Overlays

$drawrect(9,8,$eval(%_width%/4-18),40,brushcolor-null pencolor-255-255-255 blur-1 alpha-128)

$drawrect(8,48,$eval(%_width%/4-16),$eval(%_height%-56),brushcolor-255-255-255 pencolor-255-255-255 alpha-96 blur-4)

// PerTrack

//// Panels

$select($add($getpvar(sidebar.mode),1),

$panel(Sort,Track Display,8,48,$eval(%_width%/4-16),$eval(%_height%-56),),

$panel(Info,Track Display,8,48,$eval(%_width%/4-16),$eval(%_height%-56),),

$panel(Filter,Library Filter,8,48,$eval(%_width%/4-16),$eval(%_height%-56),)

)

$select($eval($getpvar(sort.mode)+1),

$panel(Thumbnails View,Single Column Playlist,$eval(%_width%/4),52,$eval(3*%_width%/4-8),$eval(%_height%-64),),

$panel(Icon View,Single Column Playlist,$eval(%_width%/4),8,$eval(3*%_width%/4-8),$eval(%_height%-16),),

$panel(Tile View,Single Column Playlist,$eval(%_width%/4),8,$eval(3*%_width%/4-8),$eval(%_height%-16),),

$panel(List View,Single Column Playlist,$eval(%_width%/4),8,$eval(3*%_width%/4-8),$eval(%_height%-16),),

$panel(Details View,Single Column Playlist,$eval(%_width%/4),8,$eval(3*%_width%/4-8),$eval(%_height%-16),))

//// Buttons

$button(20,18,,,,,/images\Buttons\$ifequal($getpvar(sidebar.mode),0,,Left2.PNG),/images\Buttons\Left2_h.PNG,PVAR:SET:sidebar.mode:$ifgreater($getpvar(sidebar.mode),0,$eval($getpvar(sidebar.mode)-1),0),TOOLTIP:"Previous sidebar")

$button(200,18,,,,,/images\Buttons\$ifequal($getpvar(sidebar.mode),2,,Right2.PNG),/images\Buttons\Right2_h.PNG,PVAR:SET:sidebar.mode:$ifgreater(2,$getpvar(sidebar.mode),$eval($getpvar(sidebar.mode)+1),3),TOOLTIP:"Next sidebar")

$button2(90,16,,,100,32,'$getpvar(Font.Main.inactive)$getpvar(sidebar.caption)','$getpvar(Font.Main.active)$getpvar(sidebar.caption)',PVAR:SET:sidebar.mode:$ifgreater(2,$getpvar(sidebar.mode),$eval($getpvar(sidebar.mode)+1),0),TOOLTIP:"Next mode")

$ifequal($getpvar(sort.mode),0,

$drawrect($eval(%_width%/4+16),10,$eval(3*%_width%/4-24),28,brushcolor-null pencolor-0-0-0)

$button2(350,16,,,100,32,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Title','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Title','Quicksearch for same .../Title',TOOLTIP:"Search for same Title")

$button2(500,16,,,100,32,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Artist','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Artist','Quicksearch for same .../Artist',TOOLTIP:"Search for same Artist")

$button2(650,16,,,100,32,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album','Quicksearch for same .../Album',TOOLTIP:"Search for same Album")

$button2(800,16,,,100,32,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Genre','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Genre','Quicksearch for same .../Genre',TOOLTIP:"Search for same Genre")

,)
20080327232916to4.png


You'll see the ghastly sidebar as above. :rofl:

[BREAK=Library > Sidebar > Sort (Track Display)]

This is the Sort Mode of the Sidebar. It is a Track Display panel with buttons to sort the playlist according to Sort-Group presets and to toggle between different playlist displays i.e. thumbnail, icons, tiles details etc. The Playlist Displays are different SCPL views which you can customize according to your liking. THe code for each is in the subsequent pages.

The Sort-Group presets have to be defined through the PanelsUI settings (Ctrl+P). You can sort things any way you like. (I'll upload my settings shortly)

The code for the Sort Mode is:

Code: 
// Background

// PerTrack

//// Buttons

$imageabs2(,,,,,,24,24,/images\Buttons\Library.PNG,)

$button2(50,26,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Library','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Library','SORTGROUP_PRESET:0',TOOLTIP:"$sortgroup_preset(0)")

$imageabs2(,,,,,,48,48,/images\Buttons\Song.PNG,)

$button2(74,50,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Song','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Song','SORTGROUP_PRESET:1',TOOLTIP:"$sortgroup_preset(1)")

$imageabs2(,,,,,,48,72,/images\Buttons\Album.PNG,)

$button2(74,74,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album','SORTGROUP_PRESET:2',TOOLTIP:"$sortgroup_preset(2)")

$imageabs2(,,,,,,48,96,/images\Buttons\Artist.PNG,)

$button2(74,98,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Artist','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Artist','SORTGROUP_PRESET:3',TOOLTIP:"$sortgroup_preset(3)")

$imageabs2(,,,,,,48,120,/images\Buttons\Year.PNG,)

$button2(74,122,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Year','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Year','SORTGROUP_PRESET:4',TOOLTIP:"$sortgroup_preset(4)")

$imageabs2(,,,,,,48,144,/images\Buttons\Genre.PNG,)

$button2(74,146,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Genre','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Genre','SORTGROUP_PRESET:5',TOOLTIP:"$sortgroup_preset(5)")

$imageabs2(,,,,,,48,168,/images\Buttons\Album Artist.PNG,)

$button2(74,170,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album Artist','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Album Artist','SORTGROUP_PRESET:6',TOOLTIP:"$sortgroup_preset(6)")

$imageabs2(,,,,,,48,192,/images\Buttons\Composer.PNG,)

$button2(74,194,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Composer','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Composer','SORTGROUP_PRESET:7',TOOLTIP:"$sortgroup_preset(7)")

$imageabs2(,,,,,,48,216,/images\Buttons\Lyricist.PNG,)

$button2(74,218,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Lyricist','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Lyricist','SORTGROUP_PRESET:8',TOOLTIP:"$sortgroup_preset(8)")

$imageabs2(,,,,,,48,240,/images\Buttons\Rating.PNG,)

$button2(74,242,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Rating','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Rating','SORTGROUP_PRESET:9',TOOLTIP:"$sortgroup_preset(9)")

$imageabs2(,,,,,,48,264,/images\Buttons\Directory.PNG,)

$button2(74,266,,,100,24,'$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Directory','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Directory','SORTGROUP_PRESET:10',TOOLTIP:"$sortgroup_preset(10)")

$imageabs2(,,,,,,24,300,/images\Buttons\Thumbnails.PNG,)

$button2(50,304,,,100,24,'$ifequal($getpvar(sort.mode),0,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Thumbnails','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Thumbnails',PVAR:SET:sort.mode:0,TOOLTIP:"Thumbnail View")

$imageabs2(,,,,,,24,324,/images\Buttons\Icon.PNG,)

$button2(50,328,,,100,24,'$ifequal($getpvar(sort.mode),1,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Icon','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Icon',PVAR:SET:sort.mode:1,TOOLTIP:"Icon View")

$imageabs2(,,,,,,24,348,/images\Buttons\Tile.PNG,)

$button2(50,352,,,100,24,'$ifequal($getpvar(sort.mode),2,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Tile','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Tile','SORTGROUP_PRESET:2',TOOLTIP:"Tile View")

$button2(50,352,,,100,24,'$ifequal($getpvar(sort.mode),2,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Tile','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Tile',PVAR:SET:sort.mode:2,TOOLTIP:"Tile View")

$imageabs2(,,,,,,24,372,/images\Buttons\List.PNG,)

$button2(50,376,,,100,24,'$ifequal($getpvar(sort.mode),3,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))List','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)List',PVAR:SET:sort.mode:3,TOOLTIP:"List View")

$imageabs2(,,,,,,24,396,/images\Buttons\Details.PNG,)

$button2(50,400,,,100,24,'$ifequal($getpvar(sort.mode),4,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Details','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Details',PVAR:SET:sort.mode:3,TOOLTIP:"Details View")

$button2(50,400,,,100,24,'$ifequal($getpvar(sort.mode),4,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))Details','$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)Details',PVAR:SET:sidebar.mode:1,TOOLTIP:"Details View")
Did you get this ?

20080327233022kh3.png


[BREAK=Library > Sidebar > Info (Track Display)]

Click on the Sort Bar (not the sidebar) or on the "Next" button on the Sort bar to toggle the Info mode of the Sidebar

The info mode is overkill, yet it looks good, so why not :P

To make it more functional, I use it with the details mode (toggles on automatically when in list view)

It shows the path and size of the file and some info which you can customize easily.

20080327233524sl8.png


Code: 
// Background

// PerTrack

$imageabs2(170,160,,,,,39,27,/images\Drop Shadow.png,NOKEEPASPECT)

$imageabs2(170,155,,,,,30,24,/images\NO.ART.png,NOKEEPASPECT)

$imageabs2(150,150,,,,,48,27,$replace(%path%,%filename_ext%,)*.jpg,NOKEEPASPECT)

$imageabs2(150,150,,,,,48,27,$replace(%path%,%filename_ext%,)$if2(%cover front%,$if2(%album%,$if2(%artist%,folder)).*),NOKEEPASPECT)

$alignabs(16,,$eval(%_width%-32),$eval(%_height%-24),left,bottom)

$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)

[%codec%[ $info(encoding)] 

$if(%isplaying%,$get(info)$div(1411,%__bitrate%).$substr($muldiv(1411,100,%__bitrate%),2,3):1 '('$get(info)$muldiv(%__bitrate%,100,1411)$get(anno)'%)',)

$char(10)]

[$info(tool)$char(10)]

[%bitrate% kbps] [%codec_profile%]$char(10)

[%samplerate% Hz][ %bitspersample%  bits]$char(10)

[$if2($info(mp3_stereo_mode),%channels%)$char(10)]

[$char(10)%ENCODEDBY%$char(10)]$char(10)

$div(%filesize%,1048576).$num($div($mul($mod(%_filesize%,1048576),100),1048576),2) MB$char(10)$char(10)

[%path%]
(Set the Info Mode to follow cursor mode subsequently)

20080327235602co8.jpg


[BREAK=Library > Sidebar > Filter (Library Filter)]

Click on the Info Bar or on the "Next" button on the Info bar to toggle the Filter mode of the Sidebar.

Remove the default code

20080327233716do4.png


It has been said that only mystic beings truly understand the nature of the PanelsUI Library Filter but it has been recently proved otherwise :ohyeah:

The Library Filter is a very powerful tool to make custom playlists if you get to know it.

Set item height to 20 and configure as shown

20080327233643en5.png


Code: 
$if(%_selected%,$drawrect(0,0,%_width%,20,brushcolor-255-255-255 pencolor-255-255-255 alpha-128 blur-4))

$if(%_selected%,$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))

$if(%_expanded%,$font(Segoe UI Bold Italic,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0),$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0))

$puts(xOffset,$eval(%_subidx%*24))

$ifequal(%_maxidx%,%_subidx%,

$alignabs($get(xOffset),0,$eval(%_width%-$get(xOffset)),%_height%,left,top)

,

$alignabs($get(xOffset),0,24,%_height%,center,top)

$if(%_expanded%,-,+)

$puts(xOffset,$eval($get(xOffset)+24))

$alignabs($get(xOffset),0,$eval(%_width%-$get(xOffset)),%_height%,left,top)

)

%criteria%
You'll have to make your own criteria in foobar. Mine is accoring to my directory structure. Can differentiate between Hindi, English, Punjabi, Tamil songs, oldies from recent, Sad from Upbeat if you have set your directory the right way and made some smart criteria to discriminate.:P

You can add more sidebar modes if you get familiarized with the code.

I have kept the variables very discreet.

btw, now would be a good time to make a playlist if you haven't already done so. You must first scan your music folder to import the database into foobar to see them in the filter view and then send it to a playlist.

20080327233920uz5.png


[BREAK=Library > Thumbnail View (SCPL)]

20080327233937li5.png


Row Height = 250

Group Rows = 0

Transparent Background Enabled

No group Settings

Item Settings:

Code: 
// PerTrack

$imageabs2(215,215,,,,,42,3,/images\Drop Shadow.png,NOKEEPASPECT)

$imageabs2(228,205,,,,,16,0,/images\NO.ART.png,NOKEEPASPECT)

$imageabs2(200,200,,,,,41,3,$replace(%path%,%filename_ext%,)*.jpg,NOKEEPASPECT)

$imageabs2(200,200,,,,,41,3,$replace(%path%,%filename_ext%,)$if2(%cover front%,$if2(%album%,$if2(%artist%,folder)).*),NOKEEPASPECT)

$if(%_isplaying%,$font(Segoe UI,15, bold italic shadow-128-128-128,255-255-255),$font(Segoe UI,15,bold shadow-128-128-128,255-255-255))

$alignabs(280,8,500,32,left,middle)[%title%]

$if(%_isplaying%,$font(Segoe UI,15, italic shadow-128-128-128,255-255-255),$font(Segoe UI,15,shadow-128-128-128,255-255-255))

$alignabs(280,40,400,32,left,middle)[%artist%]

$alignabs(280,72,400,32,left,middle)[$if2(%album%,)[$if([%date%], $char(40)%date%$char(41),)]]

$alignabs(280,108,400,32,left,middle)[$if([%tracknumber%],Track %tracknumber%,)]

$imageabs2(,,,,,,280,180,/images\Rating\$if(%rating%,$ifgreater(%rating%,5,5,%rating%),0)_star.PNG,)

// PerSecond

$font(Segoe UI,15,bold shadow-128-128-128,255-255-255)

$alignabs(280,140,200,32,left,middle)[%_time_elapsed% / ]%_length%
20080327234724ap1.jpg


All right, this was rushed.

The thumbnail mode is just a spacer for things to come. Not very useful. You can scroll through the playlist but due to the deliberate large size of the thumbnails, i doubt anyone would find it useful. Added buttons for search for the same Artist/Genre/Album etc. customize it to your liking.

However, the icon view, tile view and list view are very usable.

Click the Icons button in the Sort mode of the sidebar to toggle the Icon View.

[BREAK=Library > Icon View (SCPL)]

Row Height = 124

Group Rows = 0

Transparent Background Enabled

Item Display:

Code: 
$if(%_selected%,$drawrect(16,16,$eval(%_width%-40),100,brushcolor-255-255-255 pencolor-255-255-255 alpha-128 blur-8))

// PerTrack

$imageabs2(110,110,,,,,16,16,/images\NO.Cover.PNG,NOKEEPASPECT)

$imageabs2(100,100,,,,,16,16,$replace(%path%,%filename_ext%,)*.jpg,NOKEEPASPECT)

$imageabs2(100,100,,,,,16,16,$replace(%path%,%filename_ext%,)$if2(%cover front%,$if2(%album%,$if2(%artist%,folder)).*),NOKEEPASPECT)

$imageabs2(100,100,,,,,16,16,/images\Cover.Overlay.PNG,NOKEEPASPECT ALPHA-192)

$if(%_isplaying%,$font(Segoe UI,11, bold italic shadow-128-128-128,255-255-255),$font(Segoe UI,11,bold shadow-128-128-128,255-255-255))

$alignabs(140,18,350,24,left,middle)[%title%]

$font(Segoe UI,11, shadow-128-128-128,255-255-255)

$alignabs(140,36,350,24,left,middle)[%artist%]

$alignabs(140,54,350,24,left,middle)[%album%]

$alignabs(140,72,350,24,left,middle)[%date%]

$imageabs2(,,,,,,140,96,/images\Rating\$if(%rating%,$ifgreater(%rating%,5,5,%rating%),0)_star.PNG,)

// PerSecond

$font(Segoe UI,11,bold shadow-128-128-128,255-255-255)

$alignabs(500,18,200,24,left,middle)[%_time_elapsed% / ]%_length%

$font(Segoe UI,11, shadow-128-128-128,255-255-255)

$alignabs(500,36,200,24,left,middle)[%codec%]

$alignabs(500,54,200,24,left,middle)[%bitrate% kbps] [%codec_profile%]

$alignabs(500,72,200,24,left,middle)[$eval(%samplerate%/1000).$substr(%samplerate%,3,3) kHz][ %__replaygain_track_gain%][ %__replaygain_album_gain%]

$alignabs(500,90,200,24,left,middle)[$if2($info(mp3_stereo_mode),%channels%)]
Code to be commented.

[BREAK=Library > Tile View (SCPL)]

My favorite mode

Row Height = 24

Group Rows = 3

Transparent Background Enabled

Group Display:

Code: 
$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)

$alignabs(4,24,%_width%,24,left,middle)%groupformat%

$drawrect($eval($calcwidth(%groupformat%)+16),36,$eval(%_width%-32-$calcwidth(%groupformat%)),2,brushcolor-0-0-0 pencolor-null)
Item Display:

Code: 
$puts(ellipse.counter,%_itemindex%)

/// Album Cover ///

$ifgreater(%_itemcount%,4,

        $imageabs2(110,110,0,$eval({$get(ellipse.counter)-1}*24),,,16,0,/images\NO.Cover.PNG,NOKEEPASPECT)

        $imageabs2(100,100,0,$eval({$get(ellipse.counter)-1}*24),,,16,0,$replace(%path%,%filename_ext%,)*.jpg,NOKEEPASPECT)

        $imageabs2(100,100,0,$eval({$get(ellipse.counter)-1}*24),,,16,0,$replace(%path%,%filename_ext%,)$if2(%cover front%,$if2(%album%,$if2(%artist%,folder)).*),NOKEEPASPECT)

        $imageabs2(100,100,0,$eval({$get(ellipse.counter)-1}*24),,,16,0,/images\Cover.Overlay.PNG,NOKEEPASPECT ALPHA-192)

,)

/// Ellipse Style ///

$font(Segoe UI,11, bold shadow-128-128-128,255-255-255)

$alignabs(140,,220,20,left,middle)

/// Ellipse Rows ///

$ifequal($get(ellipse.counter),1,[%album artist%],)

$ifequal($get(ellipse.counter),2,[%genre%],)

$ifequal($get(ellipse.counter),3,[%date%],)

$ifequal($get(ellipse.counter),4,[%publisher%],)

$font(Segoe UI,11, shadow-128-128-128,255-255-255)

$if(%_selected%,$drawrect(350,3,350,20,brushcolor-255-255-255 pencolor-255-255-255 alpha-128 blur-8))

$if(%_selected%,$font(Segoe UI,11, bold shadow-128-128-128,255-255-255),$font(Segoe UI,11, shadow-128-128-128,255-255-255))

$if(%_isplaying%,$font(Segoe UI,11, bold italic shadow-128-128-128,255-255-255),)

$alignabs(360,,30,24,left,middle)[%tracknumber%]

$alignabs(600,,80,24,left,middle)[%_time_elapsed% / ]%_length%

$alignabs(390,,200,24,left,middle)%title%
[BREAK=Library > List View (SCPL)]

Those with widescreen monitors can add more details. Unfortunately I am limited to 1024x768 ona 15".

Row Height = 24

Group Rows = 3

Transparent Background Enabled

Group Display:

Code: 
$font(Segoe UI Bold,10,glow-255-255-255 glowblur-10 glowalpha-128,0-0-0)

$alignabs(4,24,%_width%,24,left,middle)%groupformat%

$drawrect($eval($calcwidth(%groupformat%)+16),36,$eval(%_width%-32-$calcwidth(%groupformat%)),2,brushcolor-0-0-0 pencolor-null)
Item Display:

Code: 
$if(%_selected%,$drawrect(2,2,$eval(%_width%-14),21,brushcolor-255-255-255 pencolor-255-255-255 alpha-128 blur-8))

$if(%_selected%,$font(Segoe UI,11, bold shadow-128-128-128,255-255-255),$font(Segoe UI,11, shadow-128-128-128,255-255-255))

$if(%_isplaying%,$font(Segoe UI,11, bold italic shadow-128-128-128,255-255-255),)

$alignabs(8,,200,24,left,middle)[%title%]

$alignabs(220,,150,24,left,middle)[%artist%]

$alignabs(400,,200,24,left,middle)[$if2(%album%,)[$if([%date%], $char(40)%date%$char(41),)]]

//// Rating

$imageabs2(,,,,,,$sub(%_width%,90),4,/images\Rating\$if(%rating%,$ifgreater(%rating%,5,5,%rating%),0)_star.PNG,)
[BREAK=View (Track Display)]

Code: 
// Background

$drawrect(,$eval(%_height%-45),$eval(%_width%),44,brushcolor-null pencolor-255-255-255 blur-1 alpha-128)

$imageabs2($eval(%_width%),32,,,,,,$eval(%_height%-44),/images\Gloss.PNG, alpha-128 NOKEEPASPECT)

// PerTrack

//// Panels

$select($add($getpvar(view.mode),1),

$panel(Channel spectrum panel,Channel spectrum panel,8,8,$eval(%_width%-16),$eval(%_height%-64),),

$panel(Cover flow,Cover flow,8,8,$eval(%_width%-16),$eval(%_height%-64),),

$panel(Shpeck,Shpeck,8,8,$eval(%_width%-16),$eval(%_height%-64),),

$panel(WMP Visualizations,WMP Visualizations,8,8,$eval(%_width%-16),$eval(%_height%-64),))

//// Buttons

$button(10,$eval(%_height%-42),0,,36,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_left.PNG,PVAR:SET:view.mode:$ifgreater($getpvar(view.mode),0,$eval($getpvar(view.mode)-1),0),TOOLTIP:"Previous")

$button(10,$eval(%_height%-42),36,,36,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_right.PNG,PVAR:SET:view.mode:$ifgreater(3,$getpvar(view.mode),$eval($getpvar(view.mode)+1),3),TOOLTIP:"Next")

$button(10,$eval(%_height%-42),72,,18,36,/images\Buttons\Nav.PNG,/images\Buttons\Nav_up.PNG,PVAR:SET:view.mode:$ifgreater(3,$getpvar(view.mode),$eval($getpvar(view.mode)+1),3),TOOLTIP:"Up")

$button2(200,$eval(%_height%-34),0,0,100,32,'$ifequal($getpvar(view.mode),0,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Spectrum','$getpvar(Font.Main.active)Spectrum',PVAR:SET:view.mode:0,TOOLTIP:"Toggle Spectrum"),

$button2(400,$eval(%_height%-34),0,0,100,32,'$ifequal($getpvar(view.mode),1,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Cover Flow','$getpvar(Font.Main.active)Cover Flow',PVAR:SET:view.mode:1,TOOLTIP:"Toggle Cover Flow"),

$button2(600,$eval(%_height%-34),0,0,108,32,'$ifequal($getpvar(view.mode),2,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Visualizations','$getpvar(Font.Main.active)Visualizations',PVAR:SET:view.mode:2,TOOLTIP:"Toggle Visualizations"),

$button2(800,$eval(%_height%-34),0,0,100,32,'$ifequal($getpvar(view.mode),3,$getpvar(Font.Main.active),$getpvar(Font.Main.inactive))Lyrics','$getpvar(Font.Main.active)Lyrics',PVAR:SET:view.mode:3,TOOLTIP:"Toggle Lyrics")
[BREAK=Details (Track Display)]

Code: 
// Global

// Background

// PerTrack

$panel(Explorer Tree,Explorer Tree,8,8,$eval(%_width%/4-16),$eval($eval(%_height%-16)/2),)

$panel(Playlist switcher,Playlist switcher,8,$eval($eval(%_height%-16)/2+8),$eval(%_width%/4-16),$eval($eval(%_height%-16)/2),)

$panel(Columns Playlist,Columns Playlist,$eval(%_width%/4),8,$eval(3*%_width%/4-8),$eval(%_height%-16),)
 
  • Like
Reactions: 2 people
Click to expand...
this is gr8...thought you wouldn't be putting this up :) also, is it only me or the screenies are yet to be uploaded??
 
^^what does? did you chek out his previous thread on this, where he had posted the screenies?? it was awssum :thumb:

oops..he's posted the link above, chek that
 
Asidxxx said:
^^what does? did you chek out his previous thread on this, where he had posted the screenies?? it was awssum :thumb:

oops..he's posted the link above, chek that
Click to expand...

the aero effect tweak/mod/theme for xp looks horrible :no:

& i did see the screenies ;)
 
bro, Udit. You can't have glass (transparency plus blur) in the current foobar in xp.

foobar is however more robust than wmp or winamp.

If you are sold out on Aero in Vista :no:, well it is easy to adapt the code to use vista's Aero in foobar in vista, but you'll have to wait for someone to code it or diy as I won't be migrating to vista anytime soon.

Although the "Aero effect" is just a transparent png, this config is not about, the "Aero effect". It is about a much more usable and customizable media player. Each and every aspect of the config can be changed, from the fonts,colors, images, effects used to whatever is shown/hidden by just manipulating the code.

The final look is well worth the effort. So I guess, for the time being, settle for this.

btw, people don't be intimidated by the code, I will update the thread with step by step screenies.

EDIT: Some Screenies added. Wud take a couple of days to complete the tutorial.
 
Udit said:
looks horrible :no:
Click to expand...

+1 .. Its really impossible to read text ../ But still a gr8 guide.. Really helpful in tweaking XP :D

Reps added :hap2:

Edit: Screw it : Spread around :@ :@ :@ :@

P.s : Customizing Linux is much easier as it doesn't require all that copy pasting of codes :P :bleh:
 
hey, if you don't like how the fonts look, you can customize them to your liking.

I know the white font on the top navigation bar is not readable but you can customize the code according to your liking. You may even use plain text if you choose to. i'll be posting the links to the Panels UI configuration guide. Then you'll appreciate its true power.

Cudn't post today. went to NP. Dead tired. btw, foobar and AHK are two things which are not letting me switch permanently to Ubuntu.
 
Is it finished, yet... your blurb at the beginning says it's not... so i have been holding out going through the guide properly until it is all done :)
 
some things came up, hence haven't been able to spend time on my computer.

(Udit's comments were a bit disheartening so I moved the tutorial a bit low in my priorities :( )

The tutorial still needs a couple of hours to complete. It will be done within the week :), but it would be good if you guys got familiar with the code by checking out the wiki at hydrogenaudio
 
Status
Not open for further replies.
Top Bottom